0 REM *******************************
1 REM *** 1750/1764 REU SLIDESHOW ***
2 REM *** DESIGNED AND WRITTEN BY ***
3 REM *** - JAMES HASTINGS-TREW - ***
4 REM ***      JULY 19,1988       ***
5 REM ***  AT THE SUGGESTION OF   ***
6 REM ***    JUDITH M. BALDWIN    ***
7 REM ***    OF THE E.C.C.U.G.    ***
8 REM *******************************
9 :
10 IF A=1THEN39
11 IF X=0THENX=1:LOAD"FASTBOOT",8,1
12 IFX=1THENX=2:SYS51200:LOAD"DISSOLVE",8,1
13 IFX=2THEN19
14 SYS34592:POKE53281,PEEK(34576)
15 SYS34592+3
16 RETURN
17 POKE53281,0:SYS34592+6:SYS34592+9
18 RETURN
19 POKE53280,0:POKE53281,0
20 IFA=1GOTO40
21 PRINT"[147][158]     1750/1764 [203]OALAPAINT [211]LIDE [211]HOW    "
22 PRINT"[159] [196]O YOU HAVE A [210]AM [197]XPANSION [213]NIT        INSTALLED? <Y/N>"
23 RU=0:POKE198,0:WAIT198,1:GETA$:IFA$="Y"THENRU=1:GOSUB87:GOTO25
24 IFA$<>"N"THEN23
25 INPUT" [197]NTER TIME (SEC.) FOR EACH PICTURE";TM:IFTM<0ORTM>59THEN25
26 TM=TM*60
27 PRINT:PRINT" [201]NSERT DATA DISK IN DRIVE <RETURN>"
28 GETA$:IFA$=""THEN28
29 DIMF$(16):POKE198,0
30 GOSUB 46
31 IFNN=0THENPRINT"[147]SORRY, NO KOALA PICTURES ON THIS DISK":END
32 PRINT"PRESS ANY KEY DURING THE SLIDE SHOW TO  STOP"
33 GS=0
34 IFGS=NN THEN RO=1:GOTO33
35 G$=LEFT$(F$(GS),15)
36 FC=PEEK(53281):CC=PEEK(646)
37 IF RU=1 AND RO=1 THEN GOSUB 75:GOTO 40
38 A=1:LOADG$,8,1
39 IF RU=1 AND RO=0 THEN GOSUB 63
40 GOSUB17:GOSUB14:TI$="000000"
41 IFTI<TMTHEN41
42 GS=GS+1:GETA$:IFA$=""THEN34
43 GOSUB17
44 PRINT"[147]DONE!":POKE53281,0
45 END
46 REM DIRECTORY READ
47 PRINT"[147][158]LIST OF ALL KOALA PICTURES ON THIS DISK"
48 OPEN15,8,15:OPEN5,8,5,"#":T=18:S=1:NN=0:Z$=CHR$(0)
49 PRINT#15,"U1:"5;0;T;S:PRINT#15,"B-P:"5;0:GET#5,T$,S$
50 T=ASC(T$+Z$):S=ASC(S$+Z$):BP=5:FL=1
51 PRINT#15,"B-P:"5;BP:GET#5,A$:IFA$="[129]"THENGOSUB56
52 BP=BP+32:FL=FL+1:IFFL<>9THEN51
53 IFT=18THEN49
54 CLOSE5:CLOSE15:T$="":S$="":A$="":N=FRE(0)
55 RETURN
56 REM LISTER
57 PRINT"[193][146]";
58 FORX=1TO15
59 F$(NN)=F$(NN)+A$:GET#5,A$:PRINTA$;
60 NEXT
61 N=FRE(0):NN=NN+1:PRINT
62 RETURN
63 REM LOAD PIC INTO REU
64 AD=GS*10010:AB=INT(AD/65536):AD=AD-(65536*AB):AH=INT(AD/256)
65 AL=AD-(AH*256)
66 POKE57096,39:REM PIC LEN HI-BYTE
67 POKE57095,17:REM PIC LEN LO-BYTE
68 POKE57094,AB:REM REU BANK
69 POKE57093,AH:REM REU ADDR HI-BYTE
70 POKE57092,AL:REM REU ADDR LO-BYTE
71 POKE57091,96:REM PIC ADDR HI-BYTE
72 POKE57090,00:REM PIC ADDR LO-BYTE
73 POKE57089,144:REM DO IT!
74 RETURN
75 REM LOAD PIC FROM REU
76 AD=GS*10010:AB=INT(AD/65536):AD=AD-(65536*AB):AH=INT(AD/256)
77 AL=AD-(AH*256)
78 POKE57096,39:REM PIC LEN HI-BYTE
79 POKE57095,17:REM PIC LEN LO-BYTE
80 POKE57094,AB:REM REU BANK
81 POKE57093,AH:REM REU ADDR HI-BYTE
82 POKE57092,AL:REM REU ADDR LO-BYTE
83 POKE57091,96:REM PIC ADDR HI-BYTE
84 POKE57090,00:REM PIC ADDR LO-BYTE
85 POKE57089,145:REM DO IT!
86 RETURN
87 REM INITIALIZE REU
88 POKE 57098,0:REM ADDR CONTROL
89 POKE 57097,128:REM INTERRUPTS
90 RETURN